parser3-lib/sql/SQLite.p at main · artlebedev/parser3-lib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
############################################################
# $Id: SQLite.p,v 1.3 2012-10-01 00:53:28 misha Exp $

@CLASS
SQLite

@USE
Sql.p

@BASE
Sql


@auto[]
$sServerName[SQLite]
# todo@
$sQuoteChar[`]

$server_name[sqlite]


# DATE functions

@today[]
$result[DATE('now')]


@now[]
$result[DATETIME('now')]


@year[sSource]
$result[STRFTIME('%Y', $sSource)]


@month[sSource]
$result[STRFTIME('%m', $sSource)]


@day[sSource]
$result[STRFTIME('%d', $sSource)]


@ymd[sSource]
$result[STRFTIME('%Y-%m-%d', $sSource)]


@time[sSource]
$result[TIME($sSource)]


@dateDiff[t;sDateFrom;sDateTo]
$result[^if(def $sDateTo){JULIANDAY($sDateTo)}{^self.now[]} - JULIANDAY($sDateFrom)]


@dateSub[sDate;iDays]
$result[DATE(^if(def $sDate){$sDate}{^self.today[]}, '+$iDays DAY')]


@dateAdd[sDate;iDays]
$result[DATE(^if(def $sDate){$sDate}{^self.today[]}, '-$iDays DAY')]


# functions available not for all sql servers

# MSSQL does not have anything like this
@dateFormat[sSource;sFormatString]
$result[STRFTIME('^if(def $sFormatString){$sFormatString}{%Y-%m-%d}', $sSource)]


# LAST_INSERT_ID()
@lastInsertID[sTable]
^self._execute{
	$result(^int:sql{SELECT last_insert_rowid()}[$.default{0}])
}


# STRING functions

@substring[sSource;iPos;iLength]
$result[SUBSTRING($sSource,^if(def $iPos){$iPos}{1},^if(def $iLength){$iLength}{1})]


@upper[sField]
$result[UPPER($sField)]


@lower[sField]
$result[LOWER($sField)]


@concat[*hArgs][s]
$result[^hArgs.foreach[;s]{IFNULL($s, '')}[ || ]]


# MISC functions

@password[sPassword]
$result[^math:md5[$sPassword]]


@leftJoin[sType;sTable;sJoinConditions;last;sAS]
$result[^switch[^sType.lower[]]{
	^case[from]{LEFT JOIN ^self.quote[$sTable]^if(def $sAS){ $sAS} ON ($sJoinConditions)}
	^case[where]{1 = 1^if(!def $last){ AND}}
	^case[DEFAULT]{
		^throw[$self.CLASS_NAME;Unknown join type '$sType']
	}
}]


@begin[hParams]
^self._execute{
	^void:sql{BEGIN TRANSACTION}
}
$result[]


@commit[hParams]
^self._execute{
	^void:sql{COMMIT TRANSACTION}
}
$result[]


@rollback[hParams]
^self._execute{
	^void:sql{ROLLBACK TRANSACTION}
}
$result[]